Arduino Sleep Mode e risveglio con Interrupt da DS3231

Arduino ha diverse modalita' di funzionamento, oltre a quella standard, per ridurre al minimo il consumo di una eventuale batteria. La modalita' sleep mode interna al processore prevede un watchdog che puo' essere settato al massimo ad 8 secondi; per ottenere dei tempi di sleep mode piu' lunghi di deve fornire al microprocessore un segnale dall'esterno che viene gestito come interrupt


Per fornire tale segnale esterno uno dei metodi piu' comodi e' quello di usare un RTC che preveda il canale SQW come il DS3231 (che peraltro risulta essere molto piu' preciso del DS1307)

Il DS3231 funzione su I2C per cui le connessioni sono VCC=3.3 V (attenzione), GND, SDA su A4 Arduino e SCL su A5 Arduino. In piu' si deve collegare SQW sul Pin dell'Arduino per avere segnale di risveglio

Sul DS3231 ci sono due allarmi ma ne sara' usato uno che dopo ogni utilizzo sara' spostato di 60 minuti nel futuro e subito dopo la scheda sara' messa in sleep mode in attesa di essere risvegliata

Il codice del loop riparte dall'ultima istruzione eseguita prima di essere andata in sleep

-------------------------------------------------------------------------------------------------
#include <Wire.h>
#include <RTClibExtended.h>
#include <LowPower.h>

#define wakePin 2    
RTC_DS3231 rtc;     
//-------------------------------------------------
void wakeUp()        // here the interrupt is handled after wakeup
{
}
//------------------------------------------------------------

void setup() {
  Serial.begin(9600);
  delay(3000);
  //imposta il PIN D2 per il wqakeup
  pinMode(wakePin, INPUT);;

  Wire.begin();
  rtc.begin();
  rtc.adjust(DateTime(__DATE__, __TIME__));   //imposta l'orologio in fase di compilazione col computer
  
  //elimina allarmi eventualmente presenti
  rtc.armAlarm(1, false);
  rtc.clearAlarm(1);
  rtc.alarmInterrupt(1, false);
  rtc.armAlarm(2, false);
  rtc.clearAlarm(2);
  rtc.alarmInterrupt(2, false);

  rtc.writeSqwPinMode(DS3231_OFF);
  delay(1000);
  Serial.println("Inizio");

}

//------------------------------------------------------------

void loop() {

    DateTime now = rtc.now();
    Serial.print(now.hour(),DEC);
    Serial.print(":");
    Serial.print(now.minute(),DEC);
    Serial.print(":");
    Serial.print(now.second(),DEC);
    Serial.println();
    
   //calcola la prossima ora di risveglio ovvero dopo un'ora
    DateTime nextAlarm = now + TimeSpan(0, 1, 0, 0);
  // l'ordine del timespan e' giorni,ore,minuti,secondi
    
    rtc.setAlarm(ALM1_MATCH_HOURS, nextAlarm.minute(), nextAlarm.hour(), nextAlarm.second());   //imposta l'allarme 
    rtc.alarmInterrupt(1, true);
    delay(3000); // wait for console
    attachInterrupt(0, wakeUp, LOW);          
    LowPower.powerDown(SLEEP_FOREVER, ADC_OFF, BOD_OFF);   //entra in sleep su questa istruzione
    detachInterrupt(0);                                    //execution resumes from here after wake-up
    //cancella la precedente impostazione dell'allarme 1
    rtc.armAlarm(1, false);
    rtc.clearAlarm(1);
    rtc.alarmInterrupt(1, false);
    delay(3000);
}