Setpixel su C64 (2)

 In un precedente post  avevo gia' affrontato il problema ...leggendo su codebase64 viene proposta una variante che usa delle tabelle di lookup per velocizzare il programma ma non viene presentato il codice completo. Questa e' una implementazione

.macro ClearScreen(screen, clearByte) {

lda #clearByte

ldx #0

!loop:

sta screen, x

sta screen + $100, x

sta screen + $200, x

sta screen + $300, x

sta screen + $400, x

sta screen + $500, x

sta screen + $600, x

sta screen + $700, x

sta screen + $800, x

sta screen + $900, x

sta screen + $a00, x

sta screen + $b00, x

sta screen + $c00, x

sta screen + $d00, x

sta screen + $e00, x

sta screen + $f00, x

sta screen + $1000, x

sta screen + $1100, x

sta screen + $1200, x

sta screen + $1300, x

sta screen + $1400, x

sta screen + $1500, x

sta screen + $1600, x

sta screen + $1700, x

sta screen + $1800, x

sta screen + $1900, x

sta screen + $1a00, x

sta screen + $1b00, x

sta screen + $1c00, x

sta screen + $1d00, x

sta screen + $1e00, x

sta screen + $1f00, x

inx

bne !loop-

}

.macro ClearColorRam(clearByte) {

lda #clearByte

ldx #0

!loop:

sta $0400, x

sta $0400 + $100, x

sta $0400 + $200, x

sta $0400 + $300, x

inx

bne !loop-

}

.macro Hires (){

lda $D018

//ora #%1000

ora #8

sta $D018 // VIC_ADDR + 24

}

.macro BMM (){

lda $D011

//ora #%100000

ora #32

sta $D011 // VIC_ADDR + 17

}

// costanti per la generazioni delle tabelle

// di lookup per calcolare la posizione del pixel

.const GFX_MEM = $2000

.const BitMask = $0a00

.const X_Table = $0b00

.const Y_Table_Lo = $0c00

.const Y_Table_Hi = $0d00

*=$0801 "Loader"

BasicUpstart($0810)

*=$0810 "Main" // SYS 2064

// generazione delle tabelle di lookup

ldx #$00

lda #$80

Loop1:

sta BitMask,x

ror

bcc Skip1

ror

Skip1:

tay

txa

and #%11111000

sta X_Table,x

tya

inx

bne Loop1

lda #<GFX_MEM // Can be replaced with a TXA if GFX_MEM is page aligned

Loop2:

ldy #$07

Loop3:

sta Y_Table_Lo,x

pha

SMC1:

lda #>GFX_MEM

sta Y_Table_Hi,x

pla

inx

dey

bpl Loop3

inc SMC1+1

clc

adc #$40

bcc Skip2

inc SMC1+1

Skip2:

cpx #8*25

bne Loop2

// ********************************************************

jsr $e544 // kernal clear screen

//:SetBorderColor(BLACK)

//:SetBackgroundColor(BLACK)

:Hires()

:BMM()

:ClearScreen($2000,0)

:ClearColorRam($3)

ldx #100 //posizione X del pixel

ldy #100 //posizione Y del pixel

jsr Plott

looper:

jmp looper

rts

Plott:

lda Y_Table_Hi,y

sta $fc

lda Y_Table_Lo,y

sta $fb

ldy X_Table,x

lda BitMask,x

ora ($fb),y

sta ($fb),y

rts